В статье объясняется использование ОКРУГЛ, ОКРУГЛТ, ОКРУГЛВВЕРХ, ОКРВНИЗ, ЦЕЛОЕ, ОТБР и множества других функций округления в Excel. Также приводятся примеры формул как округлить число до целых или до определенного количества десятичных знаков, до ближайшего 5, 10 или 100, извлечения дробной части, и многое другое.
В некоторых ситуациях, когда вам не нужен совершенно точный ответ, полезно использовать округление чисел. Говоря простым языком, эта операция означает удаление наименее значащих цифр, что упрощает понимание результатов, при этом сохраняя близкое к исходному значение. Другими словами, округление позволяет получить приблизительное значение с желаемой степенью точности.
В повседневной жизни оно обычно используется, чтобы упростить расчет или работу с числами. Например, вы можете воспользоваться им, чтобы сделать длинные десятичные числа короче, чтобы сообщить о результатах сложных вычислений или упростить денежные значения.
Существует множество различных способов округлить число – до целого, до указанного приращения, до простых дробей и т. д. Округление в Excel мы постараемся рассмотреть поэтому максимально подробно:
Чтобы сделать округление в Excel, существует множество функций для различных типов округления. Ниже вы найдете краткий обзор основных таких функций, а также примеры формул, которые демонстрируют, как использовать их на реальных данных в ваших таблицах.
Округление числа путем изменения формата ячейки.
Если вы хотите округлить числа в Excel исключительно для целей презентации, вы можете быстро изменить формат ячеек, выполнив следующие действия:
- Выберите ячейки, вид которых нужно изменить.
- Откройте диалоговое окно форматирования, нажав
Ctrl + 1, или же щелкните правой кнопкой мыши ячейку и выберите тот же пункт в контекстном меню. - На вкладке Число, выберите Числовой или Денежный формат, и укажите количество знаков после запятой, которое вы хотите видеть. Предварительный просмотр результата сразу же появится в поле Образец.
- Нажмите кнопку ОК, чтобы сохранить изменения и закрыть диалог.
Важно! Формат ячеек только изменяет формат отображения числа без изменения его фактического значения, хранящегося в ячейке. Поэтому в полной мере округлением это назвать нельзя. Если вы ссылаетесь на эту ячейку в любой формуле, во всех расчетах будет использоваться исходное значение. Это может оказаться существенным, когда вы производите вычисления (к примеру, рассчитываете НДС или сумму скидки), а затем считаете итоги. Часто оказывается, что если сложить на калькуляторе значения из таблицы, которую мы распечатали, то сумма не совпадёт с итоговым значением. Это как раз из-за того, что числа, которые мы видим, и реальные данные, с которыми производятся математические операции — это совсем не одно и то же.
Функции округления
В отличие от форматирования, которое изменяет только отображение, функции округления изменяют фактическое значение в ячейке.
Ниже вы найдете список функций, специально разработанных чтобы разными способами выполнить округление числа в Excel.
- ОКРУГЛ (ROUND) – до указанного числа разрядов соответствуя правилам математики округления чисел.
- ОКРУГЛВВЕРХ (ROUNDUP) – с увеличением до определённой точности.
- ОКРУГЛВНИЗ (ROUNDDOWN) – вниз до нужного числа разрядов.
- ОКРУГЛТ (MROUND) – в любую сторону до указанного кратного.
- ОКРВНИЗ (FLOOR) и ОКРВНИЗ.МАТ – с нужной точностью вниз.
- ОКРВВЕРХ (CEILING) и ОКРВВЕРХ.МАТ – с нужной точностью с увеличением.
- ЦЕЛОЕ (INT) – до ближайшего целого.
- ОТБР (TRUNC) – до нужного количества десятичных знаков.
- ЧЁТН (EVEN) – до четного целого.
- НЕЧЁТ (ODD) – до нечетного целого.
ОКРУГЛ
Функция ОКРУГЛ – это основная функция округления в Excel, которая производит усечение до нужного количества знаков.
Синтаксис: ОКРУГЛ(число; количество_цифр)
Аргументы функции: Число – это может быть число, ссылка на ячейку с числом, или рассчитанное при помощи формулы значение.
Второй аргумент определяет число разрядов, до которых нужно обрезать число. В этом аргументе можно указать положительное или отрицательное значение. В зависимости от этого мы получим округление в большую или меньшую сторону.
- Число больше 0 – означает нужное число разрядов после запятой. С его помощью вы можете уменьшить разрядность десятичной дроби.
Например, =ОКРУГЛ(57,55; 1) округляет 57,55 до 57,6.
- Если меньше 0, все десятичные разряды удаляются, и происходит округление чисел до десятков, сотен, тысяч и т. д..
Например, =ОКРУГЛ(57,55; -1) округляет 57,55 до ближайшего, кратного 10, и возвращает 60 в качестве результата.
- Если равно 0, то происходит округление до целого числа (без десятых).
Например, =ОКРУГЛ(57,55; 0) заменяет 57,55 на 58.
Функция ОКРУГЛ в Excel следует общим математическим правилам, где цифра справа от границы округления определяет, изменяется ли результат вверх или вниз.
Цифра округления – это последняя значащая цифра, которая сохраняется в результате. Она изменяется в зависимости от того, больше или меньше 5 цифра, следующая за ней:
- Если цифра справа от цифры округления равна 0, 1, 2, 3 или 4, цифра не изменяется, и значение считается округленным вниз.
- Если за цифрой следует 5, 6, 7, 8 или 9, она увеличивается на единицу, а результат округляется вверх.
На следующем рисунке показано несколько примеров, как может быть использована функция ОКРУГЛ:
ОКРУГЛВВЕРХ
При помощи функции ОКРУГЛВВЕРХ число округляется в большую сторону (от 0) до указанного количества знаков.
Синтаксис : ОКРУГЛВВЕРХ(число; количество_цифр)
Второй аргумент работает так же, как и в ОКРУГЛ, указывая число разрядов, но результат всегда рассчитывается в сторону увеличения.
ОКРУГЛВНИЗ
Она работает противоположно тому, что делает ОКРУГЛВВЕРХ, то есть можно округлить значение в меньшую сторону.
Второй аргумент работает аналогично предыдущим функциям за исключением того, что результат всегда изменяется в меньшую сторону.
ОКРУГЛТ
Округляет заданное значение до указанного кратного.
Синтаксис: ОКРУГЛТ(число; точность)
Например, формула =ОКРУГЛТ(17; 2) изменяет 17 до ближайшего кратного 2 и возвращает 18 в качестве результата.
Изменение последней оставшейся цифры в большую или в меньшую сторону зависит от величины остатка от деления числового аргумента на аргумент «точность»:
- Если остаток больше или равен половине значения аргумента, ОКРУГЛТ изменяет последнюю цифру с увеличением.
- Если остаток меньше половины аргумента, последняя цифра уменьшается.
Функция ОКРУГЛТ удобна, например, при изменении цен до удобного значения (10 копеек или 50 копеек), чтобы облегчить расчёты наличными.
Также это очень полезно, когда речь идет об округлении времени до желаемого интервала. Например, чтобы округлить время до 5 или 10 минут, просто укажите «0:05» или «0:10» в аргументе:
Примечание. Функция ОКРУГЛТ возвращает ошибку #ЧИСЛО!, когда ее аргументы имеют разные знаки:
=ОКРУГЛТ(15,51; -0.1) и =ОКРУГЛТ(-15,51; 0.1).
ОКРВНИЗ
Функция ОКРВНИЗ используется для преобразования в меньшую сторону до ближайшего кратного указанного значения.
Синтаксис : ОКРВНИЗ(число; точность)
Например, =ОКРВНИЗ(12.5; 2) означает округление 12,5 до ближайшего кратного 2, т.е. до 12.
Функция ОКРВНИЗ выполняет действия на основе следующих правил:
- Если число и точность положительны, то число уменьшается как в строках 2 и 6 на скриншоте ниже.
- Когда исходное число больше нуля, а точность – меньше, то выражение возвращает ошибку #ЧИСЛО!, как в строке 3 на скриншоте ниже.
- В случае если число отрицательное, а аргумент больше нуля, округляется вниз, как в строке 4.
- Когда исходное значение и аргумент отрицательны, то округляется в сторону нуля, как в строке 5.
- Если значение является точным кратным аргументу, никакое действие не производится.
Примечание. Число и аргумент ОКРВНИЗ должны иметь один и тот же знак, положительный или отрицательный. В противном случае будет получена ошибка.
Начиная с Excel 2013 функция была улучшена и появилась ОКРВНИЗ.МАТ. Во многом она лишена недостатков и нелогичностей своей предшественницы:
ОКРВНИЗ.МАТ(число; [точность]; [режим])
Если точность не указана, то по умолчанию подразумевается +1 для положительных чисел и -1 – для отрицательных.
Третий параметр определяет, в какую сторону преобразуются отрицательные значения. Ноль – в меньшую, единица – в большую сторону.
=ОКРВНИЗ.МАТ(-17;2;0) дает результат -18.
=ОКРВНИЗ.МАТ(-17;2;1) возвращает -16.
В остальном всё аналогично ОКРВВНИЗ.
Еще одной приятной особенностью является отсутствие ошибки, если число и точность имеют разные знаки.
ОКРВВЕРХ
Округляет с увеличением до ближайшего кратного. Имеет тот же синтаксис, что и функция ОКРВНИЗ.
Синтаксис : ОКРВВЕРХ(число; точность)
Например, формула =ОКРВВЕРХ(12,5; 2) преобразует 12,5 до ближайшего кратного 2, то есть до 14.
Функция ОКРВВЕРХ работает на основе правил, аналогичных правилам ОКРВНИЗ, за исключением того, что обычно округляется от 0 вверх.
- Если число и точность положительны, то результат увеличивается, как в строках 2 и 6 на скриншоте ниже.
- В случае если округляемая сумма положительна, а кратное — отрицательное, ОКРВВЕРХ возвращает ошибку #ЧИСЛО, как в строке 3.
- Когда число отрицательное, а точность положительная, то действие производится в сторону увеличения, как в строке 4.
- Ежели оба они отрицательны, результат преобразуется до ближайшего большего по абсолютному значению (то есть, в меньшую сторону), как в строке 5.
Учитывая некоторую нелогичность работы этой функции, в Excel 2013 Microsoft ввела функцию ОКРВВЕРХ.МАТ. Синтаксис ее:
ОКРВВЕРХ.МАТ(число; [точность]; [режим])
Второй аргумент не обязателен. При его отсутствии применяется автоматически +1 для положительных и -1 – для отрицательных чисел.
Параметр «режим» определяет направление изменения отрицательной величины: 0 – в большую сторону, 1 – в меньшую. Вы можете это видеть на скриншоте.
ЦЕЛОЕ
Из всех рассматриваемых в этом руководстве функций она, вероятно, является наиболее простой в использовании, поскольку используется только один аргумент. Как вы понимаете, округление происходит до целого числа.
Синтаксис : ЦЕЛОЕ(число)
Положительные величины округляются до 0, а отрицательные – от 0. То есть, действие происходит без учёта знака, по модулю. Например, =ЦЕЛОЕ(5.5) возвращает 6, а =ЦЕЛОЕ(-5.5) даёт результат -6.
ОТБР
Обрезает числовое значение до указанного числа знаков после запятой.
Синтаксис: ОТБР(число; [число_цифр])
Число_цифр – необязательный аргумент, определяющий точность усечения. То есть сколько десятичных разрядов должно в итоге остаться. Если опущен, то число обрезается до целого.
Функция ОТБР придерживается следующих правил:
- Если второй параметр положительный, то результат усекается до указанного количества цифр справа от десятичной точки.
- Когда он отрицательный, он усекается до указанного количества цифр слева от десятичной точки.
- Если равен нулю или вовсе отсутствует, то этом случае функция ОТБР работает аналогично ЦЕЛОЕ, поскольку обе в результате возвращают целые числа. Однако ОТБР просто удаляет дробную часть, а ЦЕЛОЕ округляет до целого.
- Например, =ОТБР(-7,4) возвращает -7, а =ЦЕЛОЕ(-7,4) – -8, потому что это ближайшее меньшее целое.
Вот как это выглядит:
ЧЁТН и НЕЧЁТ
Здесь всё достаточно просто — округляем указанную сумму до целого в определённую сторону.
НЕЧЁТ(число) — до ближайшего нечетного целого.
ЧЁТН(число) — до четного целого.
- Если аргумент не является числовым, функции возвращают ошибку #ЗНАЧ!.
- Если число отрицательное, оно изменяется в сторону уменьшения, от нуля.
Функции ЧЁТН и НЕЧЁТ могут оказаться полезными при обработке элементов, которые входят в пары.
Например:
=НЕЧЁТ(2,4) возвращает 3
=НЕЧЁТ(-2,4) – получаем -3
=ЧЁТН(2,4) равно 4
=ЧЁТН(-2,4) равно -4
Примеры формул округления числа в Excel
Как видите, существует множество функций чтобы выполнить округление в Excel числа в зависимости от конкретной цели. Надеемся, что эти примеры дадут вам некоторые подсказки о том, как быстро и правильно настроить округление чисел в Excel в соответствии с вашими задачами.
Округление десятичной дроби до нужного количества разрядов
В зависимости от ситуации вы можете округлить десятичные дроби в любую сторону или на основании математических правил округления:
Функция ОКРУГЛВВЕРХ – всегда меняет десятичную дробь в сторону увеличения.
Функция ОКРУГЛВНИЗ – делает то же самое, но назад.
ОКРУГЛ – округление числа в большую сторону, если за цифрой округления следует равная или больше 5, в противном случае – вниз.
В качестве примера округлим десятичные значения в столбце A до двух знаков после запятой. В первом аргументе вы вводите ссылку на ячейку, содержащую сумму, а во втором аргументе вы указываете количество знаков после запятой, которое вы хотите оставить.
=ОКРУГЛВВЕРХ(A3; 2) – формула округления в Excel до двух знаков после запятой вверх.
=ОКРУГЛВНИЗ(A3; 2) – уменьшение, до двух знаков после запятой.
=ОКРУГЛ(A3; 2) – изменение по стандартным правилам, в зависимости от того, больше или меньше 5 третий десятичный разряд.
Округление отрицательных чисел.
Когда дело доходит до работы с отрицательными числами, результаты, возвращаемые рассмотренными нами функциями округления Excel, могут показаться совершенно нелогичными :)
Когда функция ОКРУГЛВВЕРХ применяется к отрицательным величинам, то считается, что они округляются с увеличением, хотя на самом деле их значение уменьшается. Например, результатом =ОКРУГЛВЕРХ(-0,5; 0) будет -1, как в строке 7 на скриншоте ниже. Просто округляется абсолютное значение, без учёта знака. А потом уже подставляется минус, если он был.
Известно, что функция ОКРУГЛВНИЗ уменьшает, хотя отрицательные числа могут увеличиваться в значении. Например, формула =ОКРУГЛВНИЗ(-0,5; 0) возвращает 0, как в строке 8 ниже. Причина та же: знак «минус» отбрасывается, число округляется в меньшую сторону, а затем вновь добавляется минус. В результате по абсолютной величине результат уменьшился, но с учетом минуса перед ним — по законам математики увеличился.
Итак, логика округления отрицательных чисел очень проста. Каждый раз, когда вы используете функцию ОКРУГЛ или аналогичную ей для отрицательного числа, оно сначала преобразуется в его абсолютное значение (без знака минус), затем выполняется операция округления, и уже после этого отрицательный знак повторно применяется к результату.
При работе с отрицательными величинами рекомендую обратить внимание на функции ОКРВВЕРХ.МАТ и ОКРВНИЗ.МАТ, о которых мы рассказывали выше. Эта не совсем понятная логика там исправлена.
Как извлечь десятичную часть числа?
Если вы хотите извлечь дробную часть десятичного числа, вы можете использовать функцию ОТБР, чтобы отбросить десятичные разряды, а затем вычесть это целое из исходного числа.
=A3 - ОТБР(A3; 0)
Как показано на скриншоте ниже, формула в столбце B отлично работает как для положительных, так и для отрицательных величин.
При этом, если вы хотите получить абсолютное значение (десятичную часть без знака минус), оберните формулу в функцию ABS:
=ABS(A3-ОТБР(A3;0))
Как округлить десятичное число до целого
Как и в случае с десятичными знаками, существует несколько функций для превращения дробного числа в целое.
ОКРУГЛВВЕРХ.
Округляя число до большего целого, используйте формулу ОКРУГЛВВЕРХ с параметром, равным 0. Например, =ОКРУГЛВВЕРХ(5,5; 0) десятичное число изменяется с 5,5 до 6.
А вот для отрицательных чисел использовать =ОКРУГЛВВЕРХ(-5.5; 0) и получить в результате -6 мне кажется не совсем правильным.
При округлении отрицательных чисел, чтобы избежать путаницы, используйте
=ОКРВВЕРХ.МАТ(-5.5; -1; 0), что даёт -5. Это математически верно.
ЦЕЛОЕ или ОКРУГЛВНИЗ
Округляя до целого положительного числа с уменьшением, используйте ЦЕЛОЕ или ОКРУГЛВНИЗ также с параметром 0. Например, обе следующие формулы преобразуют 5,5 в 5:
=ОКРУГЛВНИЗ(5,5; 0)
=ЦЕЛОЕ(5,5)
Однако для отрицательных чисел они дают другие результаты — ЦЕЛОЕ преобразует отрицательные десятичные дроби, уменьшая значение, а ОКРВНИЗ делает результат больше — в сторону 0:
=ОКРУГЛВНИЗ(-5.5; 0) возвращает -5.
=ЦЕЛОЕ(-5.5) возвращает -6.
Более логично использовать –
=ОКРВНИЗ.МАТ(-5.5;-1;0) – дает -6, что соответствует правилам математики.
ОТБР
Чтобы удалить дробную часть без изменения целой части, используйте формулу ОТБР с опущенным вторым аргументом. Например, =ОТБР(5,5) обрезает десятичную часть (,5) и оставляет целую часть (5).
НЕЧЁТ или ЧЁТН
Чтобы изменить десятичную дробь до нечетного целого, используйте функцию НЕЧЁТ:
=НЕЧЁТ(5,5) возвращает 7.
Чтобы изменить десятичную дробь до четного целого, используйте функцию ЧЁТН:
=ЧЁТН(5,5) возвращает 6.
Округлить до 0,5
Microsoft Excel предоставляет 3 функции, которые позволяют округлять числа до ближайшего кратного 0,5. Можете использовать любую из них.
- Если нужно округлить вниз до 0,5, используйте функцию ОКРВНИЗ, например:
=ОКРВНИЗ(A3; 0,5).
- Чтобы изменить вверх до 0,5, примените, функцию ОКРВВЕРХ
=ОКРВВЕРХ(A3; 0,5).
- Округляя просто до 0,5, используйте функцию ОКРУГЛТ. Например, =ОКРУГЛТ(A3; 0,5).
То, как изменится сумма, зависит от остатка от деления её на второй аргумент (0,5). Если остаток равен половине от 0,5 или превышает его, то округляется в большую сторону, в противном случае – в меньшую.
Как видите, функцию ОКРУГЛТ можно использовать только для положительных значений. При применении её к отрицательным числам возвращается ошибка #ЧИСЛО!.
Округлить число до 5/10/100/1000
Округление до пяти, десяти, сотен или тысяч выполняется так же, как и до 0,5, рассмотренное в предыдущем примере.
Округлить до 5.
Вы можете использовать одну из следующих формул:
- Для того, чтобы округлить вниз до 5:
=ОКРВНИЗ($A3, 5) - Вверх до 5:
=ОКРВВЕРХ($A3, 5) - В любую сторону до 5:
=ОКРУГЛТ($A3, 5)
Округлить до 10.
Если нужно округлить ваши суммы до десятка, укажите 10 во втором аргументе:
Округлить до 100.
Округление до сотни выполняется таким же образом, с учётом того, что вы ставите 100 во втором аргументе:
Думаю, вы понимаете, что точно так же вы можете округлить число и до тысячи. Для этого просто вновь измените второй аргумент.
Те же методы можно использовать для округления чисел до других кратных величин. Например, вы можете округлить цены до 50 копеек (кратно 0,5), или время до одного дня. Кстати, о времени: знаете ли вы, как преобразовать его в ближайший час, 5 или 10 минут? Если нет, то ответы вы найдете в следующем разделе :)
Округление времени
Может возникнуть много ситуаций, когда вам нужно округлить значения времени. И опять же, вы можете использовать разные функции в зависимости от вашей цели.
Пример 1. Как округлить время до часа.
Когда время находится в столбце A, вы можете использовать одну из следующих функций чтобы округлить время до часа:
- до часа (вверх или вниз) –
=ОКРУГЛТ($A$2; "1:00")
=ОКРУГЛТ($A$2; ВРЕМЯ(1;0;0))
=ОКРУГЛ($A$2*24;0)/24
- вперёд до часа –
=ОКРВВЕРХ($A$7; "1:00")
=ОКРВВЕРХ($A$7; ВРЕМЯ(1;0;0))
=ОКРУГЛВВЕРХ($A$7*24;0)/24
- назад до часа –
=ОКРВНИЗ($A$12; "1:00")
=ОКРВНИЗ($A$12; ВРЕМЯ(1;0;0))
=ОКРУГЛВНИЗ($A$12*24;0)/24
В формулах ОКРУГЛ, ОКРУГЛВВЕРХ и ОКРУГЛВНИЗ вы умножаете значение времени на 24 (количество часов в сутках), чтобы преобразовать время в часы. Затем вы используете одну из функций округления десятичного значения до целого числа, после чего делите на 24, чтобы вернуть рассчитанное значение обратно в формат времени.
Если ваши временные метки включают значения даты, используйте функцию ЦЕЛОЕ и ОТБР. Ведь в Excel дата и время хранятся как обычные числа. Целая часть представляет дни, а дробная часть – время. Нам нужно извлечь только дробную часть, отбросив дни. Например:
=ОКРУГЛТ($A$2, "1:00") - ЦЕЛОЕ(A2)
=ОКРУГЛТ($A$2, ВРЕМЯ(1,0,0)) - ОТБР(A2)
=ОКРУГЛ($A$2*24; 0)/24 - ЦЕЛОЕ(A2)
На скриншоте показаны и другие формулы:
Важно! Чтобы результаты отображались правильно, не забудьте применить к ячейкам формат времени.
Пример 2. Округление времени до ближайших 5, 10, 15 минут.
Если вы хотите округлить время в таблице Excel до пяти или десяти минут или четверти часа, вы можете использовать те же методы, что и продемонстрированные выше. Но замените «1 час» на желаемое количество минут в формулах.
- Для округления времени в ячейке A3 до ближайших 15 минут:
=ОКРУГЛТ($A3; "00:15")
=ОКРУГЛТ($A3; ВРЕМЯ(0;15;0))
- Чтобы проделать это в большую сторону:
=ОКРВВЕРХ($A3; "00:15")
=ОКРВВЕРХ($A3; ВРЕМЯ(0;15;0))
- А теперь — в меньшую:
=ОКРВНИЗ($A3; "00:15")
=ОКРВНИЗ($A3; ВРЕМЯ(0;15;0))
Если вы знаете (или можете рассчитать), какая часть дня состоит из определенного количества минут, тогда у вас не будет проблем с использованием функций ОКРУГЛ, ОКРУГЛВВЕРХ и ОКРУГЛВНИЗ.
Например, зная, что 15 минут – это 1/96 часть дня, вы можете использовать одну из следующих формул, чтобы округлить время до ближайшей четверти часа.
- до 15 минут: =ОКРУГЛ(A3*96;0)/96
- В большую сторону: =ОКРУГЛВВЕРХ(A3*96;0)/96
- В меньшую сторону =ОКРУГЛВНИЗ(A3*96;0)/96
Мы представили вам множество способов округления в Excel.
Надеюсь, теперь вы знаете, как среди всех этих функций выбрать ту, которая лучше всего подходит для ваших нужд.
