В статье объясняются основы функции ГИПЕРССЫЛКА в Excel и приводятся несколько советов и примеров формул для ее наиболее эффективного использования.
Существует множество способов создать гиперссылку в Excel. Чтобы сделать ссылку на определенную веб-страницу, вы можете просто ввести ее URL-адрес в ячейку, нажать Enter, и Microsoft Excel автоматически преобразует запись в интерактивную гиперссылку.
Чтобы создать ссылку на другой рабочий лист или определенное место в другом файле Excel, вы можете использовать контекстное меню «Гиперссылка» или комбинацию клавиш Ctrl + К.
Но если вы хотите вставить на рабочий лист много одинаковых или похожих ссылок, то самый быстрый способ — использовать формулу гиперссылки, которая упрощает создание, копирование и редактирование гиперссылок в Excel.
Функция ГИПЕРССЫЛКА в Excel — синтаксис и способы использования
Функция ГИПЕРССЫЛКА в Excel используется для создания ссылки, которая направляет пользователя в указанное место в том же документе или открывает другой документ или веб-страницу. Используя формулу гиперссылки, вы можете ссылаться на:
- Определенное место, например ячейку или именованный диапазон в файле Excel (на существующем листе, или на другом листе, или в другой книге).
- Документ Word, презентацию PowerPoint или другой документ, хранящийся на жестком диске, в локальной сети или в Интернете.
- Закладка в документе Word.
- Веб-страница в Интернете.
- Адрес электронной почты для создания нового сообщения.
Эта функция доступна во всех версиях Excel для Office 365, Excel от 2019 до 2000. В Excel Online функцию ГИПЕРССЫЛКА можно использовать только для веб-адреса (URL).
Синтаксис функции ГИПЕРССЫЛКА следующий:
ГИПЕРССЫЛКА(адрес ; [имя])
Где:
- адрес (обязательно) — по которому необходимо перейти.
Он может быть представлен как ссылка на ячейку, содержащую ссылку, или же быть текстовой строкой, заключенной в кавычки, которая содержит путь к файлу, хранящемуся на локальном диске, или URL-адресом в Интернете.
Если указанный путь ссылки не существует или не работает, формула гиперссылки выдаст ошибку при попытке кликнуть по ней.
- имя (необязательно) — это пояснительный текст, который будет отображаться в ячейке. Чтобы было понятно, куда ведёт ссылка. Если опущено, то адрес из первого аргумента отображается как текст ссылки.
Этот аргумент может быть представлен в виде числа, текстовой строки, заключенной в кавычки, или ссылки на ячейку, содержащую нужный текст.
Щелчок по ячейке с формулой гиперссылки открывает файл или веб-страницу, указанную в аргументе адрес.
Ниже вы можете увидеть простейший пример формулы гиперссылки Excel, где A2 содержит имя, а B2 содержит адрес:
=ГИПЕРССЫЛКА(B2; A2)
Результат может выглядеть примерно так:
Ниже вы можете ознакомиться с примерами формул, демонстрирующими другие варианты использования функции ГИПЕРССЫЛКА в Excel.
Как использовать ГИПЕРССЫЛКА в Excel - примеры формул
Переходя от теории к практике, давайте посмотрим, как вы можете использовать функцию ГИПЕРССЫЛКА, чтобы открывать различные документы прямо из ваших рабочих таблиц. Мы также обсудим более сложную формулу, в которой она используется в сочетании с несколькими другими функциями для выполнения сложной задачи.
Функция Excel ГИПЕРССЫЛКА позволяет вам создавать ссылки нескольких различных типов, в зависимости от того, какое значение вы указываете в аргументе адрес. Рассмотрим, как создавать ссылки на листы, файлы, веб-страницы и другие элементы.
Гиперссылка на другой рабочий лист
Чтобы вставить гиперссылку на другой лист в той же книге, укажите перед именем целевого листа знак решетки (#), после него – восклицательный знак и имя целевой ячейки, например:
=ГИПЕРССЫЛКА("#Лист1!A1";"Лист1")
Приведенная выше формула создает гиперссылку с текстом перехода «Лист1», которая открывает Лист1 из текущей книги и устанавливает курсор в A1.
Если имя рабочего листа содержит пробелы или неалфавитные символы, оно обязательно должно быть заключено в одинарные кавычки, например:
=ГИПЕРССЫЛКА("#'Лист 1'!A1";"Лист 1")
Таким же образом можно создать гиперссылку на другую ячейку того же листа. Например, чтобы вставить гиперссылку, которая приведет вас к ячейке A1 на том же листе, используйте формулу, подобную этой:
=ГИПЕРССЫЛКА("#A1";"Перейти к ячейке А1")
Гиперссылка на другую книгу
Чтобы создать гиперссылку на другую книгу, необходимо указать полный путь к целевой книге в следующем формате:
"Диск:\Папка\Книга.xlsx"
Например:
=ГИПЕРССЫЛКА("C:\Гиперссылки\Книга2.xlsx";"Книга2")
Чтобы перейти на конкретный лист и даже в конкретную ячейку, используйте этот формат:
"[Диск:\Папка\Книга.xlsx]Лист!Ячейка"
Например, чтобы добавить гиперссылку с названием «Книга3», которая открывает Лист2 в Книга2, хранящейся в папке Гиперссылки на диске С, попробуйте следующую формулу:
=ГИПЕРССЫЛКА("[C:\Гиперссылки\Книга2.xlsx]Лист2!A1";"Книга2 Лист2 А1")
В данном случае вы используете так называемую абсолютную гиперссылку, в которой целевой адрес абсолютно зафиксирован.
Если вы планируете в ближайшее время переместить свои файлы в другое место, более целесообразно создать относительную гиперссылку примерно так:
=ГИПЕРССЫЛКА("\Гиперссылки\Книга2.xlsx";"Книга2")
И раз об этом зашел разговор, остановимся подробнее на абсолютных и относительных гиперссылках.
Абсолютные и относительные гиперссылки в Excel
Microsoft Excel поддерживает два типа ссылок: абсолютные и относительные, в зависимости от того, указываете ли вы полный или частичный адрес.
Абсолютная гиперссылка содержит полный адрес, включая протокол и доменное имя для URL-адресов, а также полный путь и имя файла для документов. Например:
Абсолютный URL: https://mister-office.pro/funktsii-excel/function-if-excel-primery.html
В Интернете общепринятой практикой является использование относительных URL-адресов. В гиперссылках Excel всегда следует указывать полные URL-адреса веб-страниц . Однако Microsoft Excel может понимать URL-адреса без протокола.
Например, если вы введете «www.mister-office.pro» в ячейку, Excel автоматически добавит протокол «http» по умолчанию и преобразует его в гиперссылку, по которой вы можете перейти.
Со ссылками на файлы немного сложнее.
При создании ссылок на файлы Excel или другие документы, хранящиеся на вашем компьютере, вы можете использовать как абсолютные, так и относительные адреса.
Абсолютная ссылка на файл Excel: C:\Excel files\Source Data\Book1.xlsx
В случае абсолютной гиперссылки путь к цели указан совершенно явно и точно и должен быть обновлен каждый раз, когда файл перемещается в другое место.
Относительная гиперссылка содержит частичный адрес. Например:
Пример относительной ссылки на файл Excel: Source data\Book1.xlsx
Относительная гиперссылка - это гиперссылка, которая содержит целевой адрес относительно адреса файла, в котором она записана.
В относительной гиперссылке отсутствующая часть пути к файлу относится к расположению активной книги. Основное преимущество этого подхода заключается в том, что вам не нужно редактировать адрес ссылки при перемещении файлов в другое место.
Например, если ваша активная книга и целевая книга находятся на диске C, а затем вы перемещаете их на диск D, относительные гиперссылки будут продолжать работать до тех пор, пока относительный путь к целевому файлу остается неизменным.
Гиперссылка на именованный диапазон
Если вы создаете гиперссылку на именованный диапазон на рабочем листе, укажите полный путь к целевому имени:
"[Диск:\Папка\Книга.xlsx]Лист!Имя"
Например, чтобы вставить ссылку на диапазон с именем «Диапазон_данных», хранящийся на Лист2 в Книга2, используйте следующую формулу:
=ГИПЕРССЫЛКА("[C:\Гиперссылки\Книга2.xlsx]Лист2!Диапазон_данных";"Книга2 Лист2 Диапазон данных")
Если вы ссылаетесь на именованный диапазон уровня рабочей книги, имя листа указывать не нужно, например:
=ГИПЕРССЫЛКА("[C:\Гиперссылки\Книга2.xlsx]Диапазон_данных_1";"Диапазон данных 1")
Гиперссылка для открытия файла, хранящегося на жестком диске
Чтобы создать ссылку, открывающую другой документ, укажите полный путь к этому документу в следующем формате:
"Диск:\Папка\имя_файла.расширение"
Например, чтобы открыть документ Word с именем Прайс-лист, который хранится в папке Word files на диске D, используйте следующую формулу:
=ГИПЕРССЫЛКА("D:\Word files\Прайс-лист.docx";"Прайс лист")
Гиперссылка на закладку в документе Word
Чтобы сделать гиперссылку на определенное место в документе Word, заключите путь к документу в [квадратные скобки] и используйте закладку , чтобы определить место, к которому вы хотите перейти.
Например, следующая формула добавляет гиперссылку на закладку с именем Таблица_скидок в файле Цены.docx :
=ГИПЕРССЫЛКА("[C:\Гиперссылки\Цены.docx]Таблица_скидок";"Скидки")
Гиперссылка на файл на сетевом диске
Чтобы открыть файл, хранящийся в вашей локальной сети, укажите путь к этому файлу в формате универсального соглашения об именах (UNC), в котором перед именем сервера используется двойная обратная косая черта, например:
"\\имя_сервера\папка\имя_файла.расширение"
Приведенная ниже формула создает гиперссылку под названием « Прайс на сервере», которая открывает книгу «Прайс-лист.xlsx », хранящуюся на SERVER1 в папке Alex :
=ГИПЕРССЫЛКА("\\SERVER\Alex\Прайс-лист.xlsx";"Прайс на сервере")
Чтобы открыть сетевой файл Excel на определенном листе, заключите путь к файлу в [квадратные скобки] и напишите далее имя листа, восклицательный знак (!) и ячейку, на которую указывает ссылка:
=ГИПЕРССЫЛКА("[\\SERVER\Alex\Прайс-лист.xlsx]Лист1!А1";"Прайс Лист1 на сервере")
Гиперссылка на веб-страницу
Чтобы создать гиперссылку на веб-страницу в Интернете, укажите ее URL-адрес, заключенный в кавычки, например:
=ГИПЕРССЫЛКА("https://www.mister-office.pro"4; "Перейти на Мистер Офис")
Приведенная выше формула вставляет гиперссылку под названием «Перейти на Мистер Офис», которая открывает домашнюю страницу нашего веб-сайта.
Гиперссылка для отправки электронного письма
Чтобы создать по клику на ячейку новое сообщение для определенного получателя, укажите адрес электронной почты в следующем формате:
"mailto:email_address"
Например:
=ГИПЕРССЫЛКА("mailto:alex@mister-office.pro";"Отправить email")
Приведенная выше формула добавляет гиперссылку под названием « Отправить email», и нажатие на нее создает новое почтовое сообщение.
Найти значение и создать на него гиперссылку.
При работе с большими наборами данных вы часто можете оказаться в ситуации, когда вам нужно найти конкретное значение и вернуть соответствующие данные из другого столбца. Для этого вы используете либо функцию ВПР, либо более мощную комбинацию ПОИСКПОЗ ИНДЕКС .
Но что, если вы хотите не только получить соответствующее значение, но и перейти к позиции этого значения в исходном наборе данных, чтобы просмотреть другие детали в той же строке? Это можно сделать с помощью функции ГИПЕРССЫЛКА Excel с некоторой помощью функций ЯЧЕЙКА, ИНДЕКС и ПОИСКПОЗ.
Общая формула для создания гиперссылки на первое совпадение выглядит следующим образом:
ГИПЕРССЫЛКА("#"&ЯЧЕЙКА("адрес"; ИНДЕКС( массив; ПОИСКПОЗ ( искомое_значение ; диапазон_поиска ;0))), ИНДЕКС( массив; ПОИСКПОЗ ( искомое_значение; диапазон_поиска ;0)))
Чтобы увидеть эту формулу в действии, рассмотрим следующий пример. Предположим, у вас есть список продавцов в столбце A и проданных товаров в столбце C. Вы хотите найти первый товар, проданный определенным продавцом, и создать гиперссылку на какую-либо ячейку в этой строке, чтобы вы могли перейти туда просмотреть все другие подробности, связанные именно с этим конкретным заказом.
С искомым значением в ячейке F2, списком продавцов (диапазон поиска) в A2:A10 и списком товаров (массив данных) в C2:C10 формула принимает следующий вид:
=ГИПЕРССЫЛКА("#"&@ЯЧЕЙКА("address"; ИНДЕКС($C$2:$C$10; ПОИСКПОЗ($E2;$A$2:$A$10;0))); ИНДЕКС($C$2:$C$10; ПОИСКПОЗ($E2;$A$2:$A$10;0)))
Как видно на скриншоте ниже, формула извлекает найденное значение и преобразует его в интерактивную гиперссылку, которая направляет пользователя к позиции первого совпадения в исходном наборе данных.
Если вы работаете с длинными строками данных, то может быть удобнее, чтобы гиперссылка указывала на первую ячейку в строке, где найдено совпадение. Для этого вы просто указываете другой массив в первой комбинации ИНДЕКС ПОИСКПОЗ – столбец A (в этом примере $A$2:$A$10):
=ГИПЕРССЫЛКА("#"&@ЯЧЕЙКА("address"; ИНДЕКС($A$2:$A$10; ПОИСКПОЗ($E2;$A$2:$A$10;0))); ИНДЕКС($C$2:$C$10; ПОИСКПОЗ($E2;$A$2:$A$10;0)))
Эта формула приведет вас к первой ячейке в строке с найденным товаром, который в нашем случае был обнаружен в третьей ячейке строки:
Примечание. Обратите внимание на использование абсолютных ссылок на ячейки для используемых диапазонов. Это важно, если вы планируете вставить более одной гиперссылки, скопировав формулу вниз по столбцу.
Как редактировать несколько гиперссылок одновременно
Как упоминалось в начале статьи, одним из наиболее полезных преимуществ гиперссылок на основе формул является возможность редактирования сразу нескольких формул гиперссылок за один приём с помощью функции Excel «Заменить все».
Предположим, вы хотите заменить старый URL-адрес своей компании (old-website.com) новым (new-website.com) во всех гиперссылках на текущем листе или во всей книге. Чтобы это сделать, выполните шаги, описанные ниже:
- Нажмите клавиши
Ctrl + Н, чтобы открыть вкладку «Заменить» диалогового окна «Найти и заменить». - В поле «Найти» введите текст, который вы хотите изменить (в данном примере — «old-website.com»). В поле Заменить на введите новый текст («new-website.com» в данном примере).
- В правой части диалогового окна нажмите кнопку Параметры.
- В вкладке Параметры выберите Лист или Книга в зависимости от того, хотите ли вы изменить гиперссылки только на текущем листе или на всех листах текущей книги.
- Там же в параметрах в пункте Искать в выберите Формулы.
- В качестве дополнительной меры предосторожности сначала нажмите кнопку «Найти все», и Excel отобразит список всех формул, содержащих искомый текст:
- Просмотрите результаты поиска, чтобы убедиться, что вы хотите изменить все найденные формулы. Если вы это сделаете, перейдите к следующему шагу, в противном случае уточните поиск.
- Нажмите кнопку «Заменить все». Excel заменит указанный текст во всех найденных гиперссылках и сообщит, сколько изменений было внесено.
- Нажмите кнопку Закрыть. Готово!
Аналогичным образом вы можете одновременно редактировать текст ссылки (второй параметр) во всех формулах гиперссылки. При этом убедитесь, что заменяемый текст в аргументе имя нигде не появляется в адресе, чтобы не нарушить формулы.
ГИПЕРССЫЛКА Excel не работает - причины и решения
Самая распространенная причина, по которой формула гиперссылки не работает (и первое, что вы должны проверить!) — это несуществующий или неверный путь в аргументе адрес. Если это не так, проверьте следующие две вещи:
- Если место назначения ссылки не открывается при нажатии на гиперссылку, убедитесь, что расположение ссылки указано в правильном формате. Примеры формул для создания различных типов гиперссылок можно найти выше.
- Если вместо текста ссылки появится ошибка типа ЗНАЧ! или N/A, скорее всего, проблема связана с аргументом имя вашей формулы гиперссылки.
Как правило, такие ошибки возникают, когда имя возвращается какой-либо другой функцией (функциями), например, в нашем ВПР и гиперссылке на первое совпадение. В этом случае в ячейке формулы появится ошибка #Н/Д, если искомое значение не будет найдено в таблице поиска. Чтобы предотвратить такие ошибки, вы можете рассмотреть возможность использования функции ЕСЛИОШИБКА для отображения пустой строки или некоторого понятного для пользователя текста вместо значения ошибки.
Вот как можно создавать различные ссылки с помощью функции Excel ГИПЕРССЫЛКА.
